bitzdots

1#version 330
2 
3// this shader was stolen from shadertoy user ChunderFPV
4 
5#define SCALE 8.0
6#define PI radians(180.0)
7#define TAU (PI * 2.0)
8#define CS(a) vec2(cos(a), sin(a))
9#define PT(u, r) smoothstep(0.0, r, r - length(u))
10 
11in vec2 fragCoord;
12out vec4 fragColor;
13 
14uniform float bars[512];
15 
16uniform int bars_count;    // number of bars (left + right) (configurable)
17uniform float shader_time; // shader execution time s
18uniform int bar_width;     // bar width (configurable), not used here
19uniform int bar_spacing;   // space bewteen bars (configurable)
20 
21uniform vec3 u_resolution; // window resolution
22 
23// colors, configurable in cava config file (r,g,b) (0.0 - 1.0)
24uniform vec3 bg_color; // background color
25uniform vec3 fg_color; // foreground color
26 
27uniform int gradient_count;
28uniform vec3 gradient_colors[8]; // gradient colors
29 
30// gradient map ( color, equation, time, width, shadow, reciprocal )
31vec3 gm(vec3 c, float n, float t, float w, float d, bool i) {
32  float g = min(abs(n), 1.0 / abs(n));
33  float s = abs(sin(n * PI - t));
34  if (i)
35    s = min(s, abs(sin(PI / n + t)));
36  return (1.0 - pow(abs(s), w)) * c * pow(g, d) * 6.0;
37}
38 
39// denominator spiral, use 1/n for numerator
40// ( screen xy, spiral exponent, decimal, line width, hardness, rotation )
41float ds(vec2 u, float e, float n, float w, float h, float ro) {
42  float ur = length(u);          // unit radius
43  float sr = pow(ur, e);         // spiral radius
44  float a = round(sr) * n * TAU; // arc
45  vec2 xy = CS(a + ro) * ur;     // xy coords
46  float l = PT(u - xy, w);       // line
47  float s = mod(sr + 0.5, 1.0);  // gradient smooth
48  s = min(s, 1.0 - s);           // darken filter
49  return l * s * h;
50}
51 
52void main() {
53  float t = shader_time / PI * 2.0;
54  vec4 m = vec4(0, 0, 0, 0);                 // iMouse;
55  m.xy = m.xy * 2.0 / u_resolution.xy - 1.0; // ±1x, ±1y
56  if (m.z > 0.0)
57    t += m.y * SCALE; // move time with mouse y
58  float z = (m.z > 0.0) ? pow(1.0 - abs(m.y), sign(m.y)) : 1.0; // zoom (+)
59  float e = (m.z > 0.0) ? pow(1.0 - abs(m.x), -sign(m.x))
60                        : 1.0;                   // screen exponent (+)
61  float se = (m.z > 0.0) ? e * -sign(m.y) : 1.0; // spiral exponent
62  vec3 bg = vec3(0);                             // black background
63 
64  float aa = 3.0; // anti-aliasing
65 
66  for (float j = 0.0; j < aa; j++)
67    for (float k = 0.0; k < aa; k++) {
68      vec3 c = vec3(0);
69      vec2 o = vec2(j, k) / aa;
70      vec2 uv = (fragCoord * u_resolution.xy - 0.5 * u_resolution.xy + o) /
71                u_resolution.y * SCALE * z; // apply cartesian, scale and zoom
72      if (m.z > 0.0)
73        uv =
74            exp(log(abs(uv)) * e) * sign(uv); // warp screen space with exponent
75 
76      float px = length(fwidth(uv)); // pixel width
77      float x = uv.x;                // every pixel on x
78      float y = uv.y;                // every pixel on y
79      float l = length(uv);          // hypot of xy: sqrt(x*x+y*y)
80 
81      float mc = (x * x + y * y - 1.0) / y;  // metallic circle at xy
82      float g = min(abs(mc), 1.0 / abs(mc)); // gradient
83      vec3 gold = vec3(1.0, 0.6, 0.0) * g * l;
84      vec3 blue = vec3(0.3, 0.5, 0.9) * (1.0 - g);
85      vec3 rgb = max(gold, blue);
86 
87      float w = 0.1;                                      // line width
88      float d = 0.4;                                      // shadow depth
89      c = max(c, gm(rgb, mc, -t, w * bars[0], d, false)); // metallic
90      c = max(c, gm(rgb, abs(y / x) * sign(y), -t, w * bars[1], d,
91                    false)); // tangent
92      c = max(c, gm(rgb, (x * x) / (y * y) * sign(y), -t, w * bars[2], d,
93                    false)); // sqrt cotangent
94      c = max(c, gm(rgb, (x * x) + (y * y), t, w * bars[3], d,
95                    true)); // sqrt circles
96 
97      c += rgb * ds(uv, se, t / TAU, px * 2.0 * bars[4], 2.0, 0.0); // spiral 1a
98      c += rgb * ds(uv, se, t / TAU, px * 2.0 * bars[5], 2.0, PI);  // spiral 1b
99      c +=
100          rgb * ds(uv, -se, t / TAU, px * 2.0 * bars[6], 2.0, 0.0); // spiral 2a
101      c += rgb * ds(uv, -se, t / TAU, px * 2.0 * bars[7], 2.0, PI); // spiral 2b
102      c = max(c, 0.0); // clear negative color
103 
104      c += pow(max(1.0 - l, 0.0), 3.0 / z); // center glow
105 
106      if (m.z > 0.0) // display grid on click
107      {
108        vec2 xyg = abs(fract(uv + 0.5) - 0.5) / px; // xy grid
109        c.gb += 0.2 * (1.0 - min(min(xyg.x, xyg.y), 1.0));
110      }
111      bg += c;
112    }
113  bg /= aa * aa;
114  bg *= sqrt(bg) * 1.5;
115 
116  fragColor = vec4(bg, 1.0);
117}