openAgent

1{
2  lib,
3  stdenv,
4  bun,
5  nodejs,
6  darwin,
7  electron_41,
8  makeWrapper,
9  writableTmpDirAsHomeHook,
10  autoPatchelfHook,
11  copyDesktopItems,
12  makeDesktopItem,
13  opencode,
14}:
15let
16  electron = electron_41;
17in
18stdenv.mkDerivation (finalAttrs: {
19  pname = "opencode-desktop";
20  inherit (opencode)
21    version
22    src
23    node_modules
24    patches
25    ;
26 
27  nativeBuildInputs = [
28    bun
29    nodejs
30    makeWrapper
31    writableTmpDirAsHomeHook
32  ]
33  ++ lib.optionals stdenv.hostPlatform.isLinux [
34    autoPatchelfHook
35    copyDesktopItems
36  ]
37  ++ lib.optionals stdenv.hostPlatform.isDarwin [
38    # Ad-hoc sign the .app: --config.mac.identity=null below skips signing.
39    darwin.autoSignDarwinBinariesHook
40  ];
41 
42  buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
43    (lib.getLib stdenv.cc.cc)
44  ];
45 
46  desktopItems = lib.optional stdenv.hostPlatform.isLinux (makeDesktopItem {
47    name = "ai.opencode.desktop";
48    desktopName = "OpenCode";
49    exec = "opencode-desktop %U";
50    icon = "ai.opencode.desktop";
51    # Electron 41 derives X11 WM_CLASS from app.name.
52    startupWMClass = "OpenCode";
53    categories = [ "Development" ];
54  });
55 
56  env = opencode.env // {
57    ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
58  };
59 
60  postPatch =
61    # NOTE: Relax Bun version check to be a warning instead of an error
62    ''
63      substituteInPlace packages/script/src/index.ts \
64        --replace-fail 'throw new Error(`This script requires bun@''${expectedBunVersionRange}' \
65                       'console.warn(`Warning: This script requires bun@''${expectedBunVersionRange}'
66    ''
67    # https://github.com/electron/electron/issues/31121
68    # mac builds use a .app bundle which doesnt have this issue
69    + lib.optionalString stdenv.isLinux ''
70      BASE_PATH=packages/desktop
71      FILES=(src/main/windows.ts)
72      for file in "''${FILES[@]}"; do
73        substituteInPlace $BASE_PATH/$file \
74          --replace-fail "process.resourcesPath" "'$out/opt/opencode-desktop/resources'"
75      done
76    '';
77 
78  preBuild = ''
79    cp -r "${electron.dist}" $HOME/.electron-dist
80    chmod -R u+w $HOME/.electron-dist
81 
82    cp -R ${finalAttrs.node_modules}/. .
83    patchShebangs node_modules
84    patchShebangs packages/*/node_modules
85  '';
86 
87  buildPhase = ''
88    runHook preBuild
89 
90    cd packages/desktop
91 
92    bun run build
93    npx electron-builder --dir \
94      --config electron-builder.config.ts \
95      --config.mac.identity=null \
96      --config.electronDist="$HOME/.electron-dist"
97 
98    runHook postBuild
99  '';
100 
101  installPhase = ''
102    runHook preInstall
103  ''
104  + lib.optionalString stdenv.hostPlatform.isDarwin ''
105    mkdir -p $out/Applications
106    mv dist/mac*/*.app $out/Applications
107    makeWrapper "$out/Applications/OpenCode.app/Contents/MacOS/OpenCode" $out/bin/opencode-desktop
108  ''
109  + lib.optionalString stdenv.hostPlatform.isLinux ''
110    mkdir -p $out/opt/opencode-desktop
111    cp -r dist/linux*-unpacked/{resources,LICENSE*} $out/opt/opencode-desktop
112    install -Dm644 resources/icons/32x32.png \
113      "$out/share/icons/hicolor/32x32/apps/ai.opencode.desktop.png"
114    install -Dm644 resources/icons/64x64.png \
115      "$out/share/icons/hicolor/64x64/apps/ai.opencode.desktop.png"
116    install -Dm644 resources/icons/128x128.png \
117      "$out/share/icons/hicolor/128x128/apps/ai.opencode.desktop.png"
118    install -Dm644 resources/icons/128x128@2x.png \
119      "$out/share/icons/hicolor/256x256/apps/ai.opencode.desktop.png"
120    install -Dm644 resources/icons/icon.png \
121      "$out/share/icons/hicolor/512x512/apps/ai.opencode.desktop.png"
122    install -Dm644 resources/ai.opencode.desktop.metainfo.xml \
123      "$out/share/metainfo/ai.opencode.desktop.metainfo.xml"
124    makeWrapper ${lib.getExe electron} $out/bin/opencode-desktop \
125     --inherit-argv0 \
126     --set ELECTRON_FORCE_IS_PACKAGED 1 \
127     --add-flags $out/opt/opencode-desktop/resources/app.asar \
128     --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
129  ''
130  + ''
131    runHook postInstall
132  '';
133 
134  autoPatchelfIgnoreMissingDeps = [
135    "libc.musl-x86_64.so.1"
136  ];
137 
138  meta = {
139    description = "OpenCode Desktop App";
140    mainProgram = "opencode-desktop";
141    inherit (opencode.meta) homepage license platforms;
142  };
143})
144