openAgent

1{
2  lib,
3  stdenvNoCC,
4  callPackage,
5  bun,
6  nodejs,
7  sysctl,
8  makeBinaryWrapper,
9  models-dev,
10  ripgrep,
11  installShellFiles,
12  versionCheckHook,
13  writableTmpDirAsHomeHook,
14  node_modules ? callPackage ./node-modules.nix { },
15}:
16stdenvNoCC.mkDerivation (finalAttrs: {
17  pname = "opencode";
18  inherit (node_modules) version src;
19  inherit node_modules;
20 
21  nativeBuildInputs = [
22    bun
23    nodejs # for patchShebangs node_modules
24    installShellFiles
25    makeBinaryWrapper
26    models-dev
27    writableTmpDirAsHomeHook
28  ];
29 
30  postPatch = ''
31    # NOTE: Relax Bun version check to be a warning instead of an error
32    substituteInPlace packages/script/src/index.ts \
33      --replace-fail 'throw new Error(`This script requires bun@''${expectedBunVersionRange}' \
34                     'console.warn(`Warning: This script requires bun@''${expectedBunVersionRange}'
35  '';
36 
37  configurePhase = ''
38    runHook preConfigure
39 
40    cp -R ${finalAttrs.node_modules}/. .
41    patchShebangs node_modules
42    patchShebangs packages/*/node_modules
43 
44    runHook postConfigure
45  '';
46 
47  env.MODELS_DEV_API_JSON = "${models-dev}/dist/_api.json";
48  env.OPENCODE_DISABLE_MODELS_FETCH = true;
49  env.OPENCODE_VERSION = finalAttrs.version;
50  env.OPENCODE_CHANNEL = "prod";
51 
52  buildPhase = ''
53    runHook preBuild
54 
55    cd ./packages/opencode
56    bun --bun ./script/build.ts --single --skip-install
57    bun --bun ./script/schema.ts schema.json
58 
59    runHook postBuild
60  '';
61 
62  installPhase = ''
63    runHook preInstall
64 
65    install -Dm755 dist/opencode-*/bin/opencode $out/bin/opencode
66    install -Dm644 schema.json $out/share/opencode/schema.json
67 
68    wrapProgram $out/bin/opencode \
69      --prefix PATH : ${
70        lib.makeBinPath (
71          [
72            ripgrep
73          ]
74          # bun runs sysctl to detect if running on rosetta2
75          ++ lib.optional stdenvNoCC.hostPlatform.isDarwin sysctl
76        )
77      }
78 
79    runHook postInstall
80  '';
81 
82  postInstall = lib.optionalString (stdenvNoCC.buildPlatform.canExecute stdenvNoCC.hostPlatform) ''
83    # trick yargs into also generating zsh completions
84    installShellCompletion --cmd opencode \
85      --bash <($out/bin/opencode completion) \
86      --zsh <(SHELL=/bin/zsh $out/bin/opencode completion)
87  '';
88 
89  nativeInstallCheckInputs = [
90    versionCheckHook
91    writableTmpDirAsHomeHook
92  ];
93  doInstallCheck = true;
94  versionCheckKeepEnvironment = [ "HOME" "OPENCODE_DISABLE_MODELS_FETCH" ];
95  versionCheckProgramArg = "--version";
96 
97  passthru = {
98    jsonschema = "${placeholder "out"}/share/opencode/schema.json";
99    env = finalAttrs.env;
100  };
101 
102  meta = {
103    description = "The open source coding agent";
104    homepage = "https://opencode.ai";
105    license = lib.licenses.mit;
106    mainProgram = "opencode";
107    inherit (node_modules.meta) platforms;
108  };
109})
110